Amiga Format CD 43/Amiga Format CD43 (1999)(Future Publishing)(GB)(Track 1 of 2)[!][issue 1999-09].iso/-serious-/comms/other/hurl!/install

Text File | 1999-06-14 | 5KB | 200 lines

; A General Installation Script
; Copyright © 1998 by Ralph Torchia
; $VER:GenInstallScript v1.1 (16.09.1998)
; $DESCRIPTION: Customized for Hurl v2 - Install v1.8 (10.04.1999)

(set @PRGVersion "1.8")

;-------------- Get Current Hurl version  ---------------
(set vernum_new (getversion "hurl"))
(set ver_new (/ vernum_new 65536))
(set rev_new (- vernum_new (* ver_new 65536) ) )

;-------------- Introduce Ourselves ------------------
(welcome
  ("\nWelcome!\n\n")
  ("    This script will copy the program Hurl\nto your system.\n")
  ("    Please follow the intaller's instruction to install\n\n")
)

;-------------- Are we installing for YAM only? ---------------
(set #yamchoice
  (askchoice
    (prompt "Do you want to install Hurl only for YAM?")
    (help @askchoice-help)
    (choices "Yes"
             "No")
    (default 0)
  )
)

;-------------- Choice #1 = Install to YAM: directory ---------------
(if (= #yamchoice 0)
 (
  (set #homedir "YAM:")

  (if (not (exists #homedir (noreq)))
    (
      (set #homedir
        (askdir
          (prompt "Where is the program YAM located?")
          (help " Please locate the YAM directory. (The main program YAM is located within it).")
          (default #homedir)
        )
      )
    )
  )

  (set @default-dest (tackon #homedir "Rexx/"))
  (set @hurlfile-dest (tackon @default-dest "Hurl"))

  (if (not (exists @default-dest (noreq)))
    (
      (makedir @default-dest
        (prompt "Directory "@default-dest" does not exist!\nCreate it now?")
        (help "YAM places all its scripts within the Rexx folder.  Proceeding with this installation will result in the YAM:Rexx folder being created.")
        (confirm 0)
      )
    )
  )

  (set vernum_old (getversion @hurlfile-dest))
  (set ver_old (/ vernum_old 65536))
  (set rev_old (- vernum_old (* ver_old 65536) ) )
  (message
    ("You are about to install Hurl version %ld.%ld.\n" ver_new rev_new)
    ("You currently have version %ld.%ld installed" ver_old rev_old)
   )

  (if (exists @default-dest (noreq))
      (
        (copyfiles
          (prompt "Copying Hurl to " @default-dest)
          (help @copyfiles-help)
          (source "Hurl")
          (dest @default-dest)
          (files)
        )
      )
  )

  (if (exists @hurlfile-dest (noreq))
   (
    (set #mode
      (askchoice
        (prompt "Do you want to configure YAM for Hurl?")
        (help @askchoice-help)
        (choices "Yes - Configure YAM for Hurl usage"
                 "Yes - Configure YAM and set Hurl to auto mode"
                 "No  - I'll do it myself!")
        (default 0)
      )
    )

    (if (= #mode 0)
      ((rexx "configyam4hurl.rexx"))
    )

    (if (= #mode 1)
      ((rexx "configyam4hurl.rexx auto"))
    )

    (set #yamsize (getsize "YAM:YAM"))
    (if (= #yamsize 523612)
      (
        (set #patch
          (askchoice
            (prompt "YAM v2p7 has a bug which prevents the use of Hurl.  Would you like to patch YAM right now? (NOTE: If your copy of YAM2p7 is already patched, then doing this a second time will unpatch YAM)")
            (help @askchoice-help)
            (choices "Yes"
                     "No")
            (default 0)
          )
        )
        (if (= #patch 0)
          ((run "YamOpenURLPatch"))
        )
      )
    )
   )
  )

  (if (not (exists @hurlfile-dest (noreq)))
    ((abort "You did not locate the YAM directory and program correctly!\nPlease try again...\n"))
  )
 )
)

;-------------- Choice #2 = Install to User's system instead ---------------
(if (= #yamchoice 1)
 (
  (set #homedir "c:")
  (set #homedir
    (askdir
      (prompt "Where do you want to install Hurl to?")
      (help "Please choose a dirctory to install Hurl to.  C: is a good choice.")
      (default #homedir)
    )
  )

  (set vernum_old (getversion (tackon #homedir "Hurl")))
  (set ver_old (/ vernum_old 65536))
  (set rev_old (- vernum_old (* ver_old 65536) ) )
  (message
    ("You are about to install Hurl version %ld.%ld.\n" ver_new rev_new)
    ("You currently have version %ld.%ld installed" ver_old rev_old)
   )

  (if (exists #homedir (noreq))
    (
      (set @default-dest #homedir)
      (copyfiles
        (prompt "Copying Hurl to " @default-dest)
        (help @copyfiles-help)
        (source "Hurl")
        (dest @default-dest)
        (files)
      )
    )
  )
 )
)

;-------------- Install Hurl.guide? ---------------
(set #guidechoice
  (askchoice
    (prompt "Do you want to install the Hurl Guide file?")
    (help @askchoice-help)
    (choices "Yes"
             "No")
    (default 0)
  )
)

(if (= #guidechoice 0)
  (
    (set #guidedir "Help:")
    (set #guidedir
      (askdir
        (prompt "Where do you want to install Hurl.guide to?")
        (help "Please choose a dirctory to install Hurl.guide to.  Help: is a good choice.")
        (default #guidedir)
      )
    )
   (if (exists #guidedir (noreq))
     (
       (copyfiles
         (prompt "Copying Hurl.guide to " #guidedir)
         (help @copyfiles-help)
         (source "Hurl.guide")
         (dest #guidedir)
         (files)
       )
     )
   )
  )
)

(exit "Done installing Hurl.\n\nRemember, this is Emailware!")